Bienvenu(e)! Identification Créer un nouveau profil

Recherche avancée

problème sas/af - formulaire inscription

Envoyé par jed 
Ce forum est en lecture seule. C'est une situation temporaire. Réessayez plus tard.
jed
problème sas/af - formulaire inscription
05 février 2008, 17:43
Bonjour à tous.
Donc voila j'ai un souci sur sas/af.
Je veux créer un formulaire d'inscription et une fois ce formulaire rempli, les données entrées par l'utilisateur sont stockées dans une table sas. Voici mon programme, loin d'etre parfait (nb :je débute en sas) puisqu'il ne fonctionne pas ! (la frame s'affiche , mais aucune donnée écrite dans la table).
Merci d'avance pour vos réponses.

init:
Return;

PB_VALIDER_INSCR:
L_text = makelist();
L_text = insertc(L_text,"Vous n'avez pas saisi votre nom",1);
L_text1 = makelist();
L_text1 = insertc(L_text1,"Vous n'avez pas saisi votre prénom",1);
L_text2 = makelist();
L_text2 = insertc(L_text2,"Vous n'avez pas saisi votre adresse",1);
L_text3 = makelist();
L_text3 = insertc(L_text3,"Vous n'avez pas saisi votre code postal",1);
L_text4 = makelist();
L_text4 = insertc(L_text4,"Vous n'avez pas saisi votre ville",1);
L_text5 = makelist();
L_text5 = insertc(L_text5,"Vous n'avez pas saisi votre pseudo",1);
L_text6 = makelist();
L_text6 = insertc(L_text6,"Vous n'avez pas saisi votre mail",1);
L_text7 = makelist();
L_text7 = insertc(L_text7,"Vous n'avez pas saisi votre mot de passe",1);
L_text8 = makelist();
L_text8 = insertc(L_text8,"Vous n'avez pas retaper le même mot de passe",1);


If TE_NOM.Text="" then texte = messagebox(L_text,'!','Y','Erreur de saisie');
if TE_PRENOM.Text="" then texte = messagebox(L_text1,'!','Y','Erreur de saisie');
if TE_ADRESSE.Text="" then texte = messagebox(L_text2,'!','Y','Erreur de saisie');;
if TE_CODEPOSTAL.Text="" then texte = messagebox(L_text3,'!','Y','Erreur de saisie');
if TE_VILLE.Text="" then texte = messagebox(L_text4,'!','Y','Erreur de saisie');
if TE_PSEUDO.Text="" then texte = messagebox(L_text5,'!','Y','Erreur de saisie');
if TE_MAIL.Text="" then texte = messagebox(L_text6,'!','Y','Erreur de saisie');
if TE_PASSWD.Text="" then texte = messagebox(L_text7,'!','Y','Erreur de saisie');
if ((TE_PASSWDBIS.Text ne TE_PASSWD.Text) or (TE_PASSWDBIS.Text="")) then texte = messagebox(L_text8,'!','Y','Erreur de saisie');



submit continue;
data sasuser.Joueurs;
Nom = TE_NOM.Text;
Prenom= &TE_PRENOM.Text;
Adresse= &TE_ADRESSE.Text;
Code Postal= &TE_CODEPOSTAL.Text;
Ville= &TE_VILLE.Text;
Pseudo= &PSEUDO.Text;
Mail= &TE_MAIL.Text;
Mot de passe= &TE_PASSWD.Text;
run;
endsubmit;
Call ExecCMD('output');
Call display ('casfram.projet.inscription.frame');
return;
jed
Re: problème sas/af - formulaire inscription
14 février 2008, 11:17
Personne pour me répondre...
Sophie L
Re: problème sas/af - formulaire inscription
15 février 2008, 11:39
Voici les instructions pour créer et mettre à jour une table SAS
La création de la table ne se fait que si elle n'existe pas.


/************************************/
/************************************/
/**** Création de la table ****/
/************************************/
/************************************/

/* a Adpater */
TABLE = "RépertoireEnregistrementTable\Formulaire.sas7bdat";
RTABLE = "RépertoireEnregistrementTable";

/* Attribution du chemin d'enregsitrement de la table au filename "table" */
rc = filename('table',TABLE);

/* Si le filename n'a pas fonctionné */
if rc ne 0 then do;
/* affichage d'un message d'erreur */
L_TEXTE = makelist();
L_TEXTE = insertc(L_TEXTE, "Problème d'accession à la table contenant les informations des formulaires",-1);
/* Ouverture de la fenêtre d'erreur*/
MESS_ERREUR = messagebox(L_TEXTE,'S','O','ERREUR','O');
/* On libère le filename */
rc = filename('table',' ');
/* Fin des instructions */
return;
end;

/* Si la table n'existe pas */
if not fexist('table') then do;
/* Definition du libname pour l'enregistrement des selections */
rc=libname ('tab',RTABLE);
/* Si le libname n'a pas fonctionne */
if rc > 0 then do;
/* affichage d'un message d'erreur */
L_TEXTE = makelist();
L_TEXTE = insertc(L_TEXTE, "Problème d'accession au répertoire contenant la table des infos",-1);
/* Ouverture de la fenêtre d'erreur*/
MESS_ERREUR = messagebox(L_TEXTE,'S','O','ERREUR','O');
/* On libère le libname */
rc = libname('tab','');
/* On libère le filename */
rc = filename('table',' ');
/* Fin des instructions */
return;
end;

/* On cree une table FORMULAIRE.SAS7bdat, qui contiendra 3 variables: */
/* - NOM ==> Nom, */
/* - PRENOM ==> Prénom, */
/* - ADRESSE ==> Adresse, */
/* - CODEPOSTAL ==> Code Postal, */
/* - VILLE ==> Ville, */
/* - PSEUDO ==> Pseudo, */
/* - MAIL ==> Mail, */
/* - PASSWD ==> PassWord */
/* On ouvre la table FRA.FORMULAIRE pour création */
dsid=open('FRA.FORMULAIRE','N');

/* Si la creation de la table n'a pas fonctionne */
if dsid = 0 then do;
/* affichage d'un message d'erreur */
L_TEXTE = makelist();
L_TEXTE = insertc(L_TEXTE, "Problème d'ouverture de la table des infos",-1);
/* Ouverture de la fenêtre d'erreur*/
MESS_ERREUR = messagebox(L_TEXTE,'S','O','ERREUR','O');
/* On ferme la table */
dsid = close(dsid);
/* On libère le libname */
rc = libname('tab','');
/* On libère le filename */
rc = filename('table',' ');
/* Fin des instructions */
return;
end;

/* Création des variables (NomTable, NomVariable, TypeVariable, LengthVariable, LabelVariable) */
rc=newvar(dsid,'NOM', 'C', 25, 'Nom');
rc=newvar(dsid,'PRENOM', 'C', 25, 'Prénom');
rc=newvar(dsid,'ADRESSE', 'C', 100, 'Adresse');
rc=newvar(dsid,'CODEPOSTAL', 'C', 5, 'Code Postal');
rc=newvar(dsid,'VILLE', 'C', 25, 'Ville');
rc=newvar(dsid,'PSEUDO', 'C', 25, 'Pseudo');
rc=newvar(dsid,'MAIL', 'C', 100, 'Mail');
rc=newvar(dsid,'PASSWD', 'C', 25, 'PassWord');

/* Fermeture de la table des fichiers selectionnes */
dsid=close(dsid);

/* On libère le libname */
rc = libname ('tab','');
end;

/* On libère le filename */
rc = filename('table',' ');



/***************************************/
/***************************************/
/**** Mise à jour de la table ****/
/***************************************/
/***************************************/


/* Attribution du chemin d'enregistrement de la table au filename "table" */
rc = filename('table',TABLE);

/* Si le filename n'a pas fonctionné */
if rc ne 0 then do;
/* affichage d'un message d'erreur */
L_TEXTE = makelist();
L_TEXTE = insertc(L_TEXTE, "Problème d'accession à la table des infos",-1);
/* Ouverture de la fenêtre d'erreur*/
MESS_ERREUR = messagebox(L_TEXTE,'S','O','ERREUR','O');
/* On libère le filename */
rc = filename('table',' ');
/* Fin des instructions */
return;
end;

/* Definition du libname pour l'enregistrement des selections */
rc=libname ('tab',RTABLE);

/* Si le libname n'a pas fonctionné */
if rc > 0 then do;
/* affichage d'un message d'erreur */
L_TEXTE = makelist();
L_TEXTE = insertc(L_TEXTE, "Problème d'accession au répertoire contenant la table des infos",-1);
/* Ouverture de la fenêtre d'erreur*/
MESS_ERREUR = messagebox(L_TEXTE,'S','O','ERREUR','O');
/* On libère le libname */
rc = libname('tab','');
/* On libère le filename */
rc = filename('table',' ');
/* Fin des instructions */
return;
end;

/* Ouverture de la table des sauvegardes pour mise a jour */
dsid=open('TAB.FORMULAIRE','U');

/* Si l'ouverture n'a pas fonctionne */
if dsid = 0 then do;
/* affichage d'un message d'erreur */
L_TEXTE = makelist();
L_TEXTE = insertc(L_TEXTE, "Problème d'ouverture de la table des infos",-1);
/* Ouverture de la fenêtre d'erreur*/
MESS_ERREUR = messagebox(L_TEXTE,'S','O','ERREUR','O');
/* On libère le libname */
rc = libname('tab','');
/* On libère le filename */
rc = filename('table',' ');
/* Fin des instructions */
return;
end;

/* Insertion des infos */
call putvarc(dsid, varnum(dsid,"NOM"), TE_NOM.Text);
call putvarc(dsid, varnum(dsid,"PRENOM"), TE_PRENOM.Text);
call putvarc(dsid, varnum(dsid,"ADRESSE"), TE_ADRESSE.Text);
call putvarc(dsid, varnum(dsid,"CODEPOSTAL"), TE_CODEPOSTAL.Text);
call putvarc(dsid, varnum(dsid,"VILLE"), TE_VILLE.Text);
call putvarc(dsid, varnum(dsid,"PSEUDO"), TE_PSEUDO.Text);
call putvarc(dsid, varnum(dsid,"MAIL"), TE_MAIL.Text);
call putvarc(dsid, varnum(dsid,"PASSWD"), TE_PASSWD.Text);
rc=append(dsid,'NOINIT');

/* On ferme la table */
dsid=close(dsid);
/* On libère le libname */
rc=libname ('tab','');
/* On libère le filename */
rc = filename('table', " ");
Jed
Re: problème sas/af - formulaire inscription
15 février 2008, 16:28
Merci beaucoup pour ton aide sophie
zf
Re: problème sas/af - formulaire inscription
16 mars 2012, 08:05
A lot of friends and people I talk to aren‘t to sure wow gold where to get started when it comes to buying wow po. So I thought i‘d give you a little idea of something that happend to me before I began my venture to find the best www.woweuvip.fr and find out who the scammers are!!Hey there folks!